AutoHotkey Tools

Automation scripts and utilities for radiology workflows

Radiology Automation Script

Full Script

Complete AutoHotkey v2 script for radiology workflow automation including EPIC integration and dictation controls

EPIC "break the glass" automation
PowerScribe dictation controls
Visage viewer shortcuts
Configurable user credentials

Current

Download

AutoHotkey + SciTE4AHK Bundle

Development

Portable bundle including AutoHotkey v2 runtime and SciTE4AHK editor for script development

AutoHotkey v2 runtime
SciTE4AHK script editor
Portable installation
Syntax highlighting
Script compilation tools

Current

Download

Radiology Script Preview

Preview of the main radiology automation script (truncated for display)

#SingleInstance force
#Requires Autohotkey v2
CoordMode "ToolTip", "Screen"
CoordMode "Mouse", "Client"
SetTitleMatchMode 2

; Variable Definitions
USER := ""
PASS := ""
KEEPAWAKE := 0
EPIC_TITLE := "Prod"
PS := "360"
VISAGE := "Visage"
RADSMODE := false
PSEDITCTL := ""
GRAPHITE := false

; GUI Initialization
myGui := Gui()
myGui.Add("GroupBox", "x16 y0 w450 h67", "Login Information")
myGui.Add("Text", "x24 y24 w56 h23 +0x200", "Username:")
myGui.Add("Text", "x248 y24 w53 h23 +0x200", "Password:")
Edit1 := myGui.Add("Edit", "x88 y24 w134 h21")
Edit2 := myGui.Add("Edit", "x312 y24 w133 h21 +Password")
LaunchButton := myGui.Add("Button", "x16 y80 w444 h61", "Launch and Minimize Window").OnEvent("Click", LaunchButtonHandler)
myGui.Add("Text", "x16 y184 w399 h23 +0x200", "This launcher will minimize after site selection. Close the window to kill the script.")
myGui.Add("Text", "x16 y208 w360 h23 +0x200", "Alt + b = break the glass                Alt + p = enter username and password")
CheckBox1 := myGui.Add("CheckBox", "x100 y152 w120 h23", "Prevent Sleep")
Edit1.OnEvent("Change", OnEventHandler)
Edit2.OnEvent("Change", OnEventHandler)
CheckBox1.OnEvent("Click", OnEventHandler)
myGui.Title := "AutoHotkey Login Script"
myGui.OnEvent("Close", CloseHandler)
myGui.Show("w478 h235")

; GUI Handlers
OnEventHandler(*) {
    global USER := Edit1.Value
    global PASS := Edit2.Value
    global KEEPAWAKE := CheckBox1.Value
}

LaunchButtonHandler(*) {
    If not WinExist(PS) {
        Run("C:Program FilesNuance CommunicationsNextGen CommunicatorCommunicator.exe")
    }
    myGui.Minimize()
}

CloseHandler(*) {
    MsgBox("Script closed.")
    ExitApp
}

; Background Timers
SetTimer StopSleep, 100000 ; Every 100 seconds
SetTimer UpdatePSEditWindow, 500 ; Check every second

; Functions
breakGlass() {
    If WinExist(EPIC_TITLE) {
        WinActivate(EPIC_TITLE)
        Sleep(100)
        Send("Care")
        Sleep(200)
        Send("{Enter}")
        Sleep(200)
        Send("{Tab}")
        Sleep(100)
        Send("{Tab}")
        Sleep(100)
        Send("{Raw}" PASS)
        Sleep(200)
        Send("!A")
    }
}

loginSite() {
    Send("{Raw}" USER)
    Sleep(200)
    Send("{Tab}")
    Sleep(200)
    Send("{Raw}" PASS)
    Sleep(200)
    Send "{Enter}"
}

StopSleep(*) {
    if (KEEPAWAKE) {
        ; Use screen coordinates for this function to avoid client area issues
        ; Store current global setting and temporarily switch to screen mode
        CoordMode("Mouse", "Screen")

        ; Store current mouse position
        MouseGetPos(&currentX, &currentY)

        ; Move mouse by 1 pixel right, then back
        ; This creates minimal movement that won't interfere with work
        MouseMove(currentX + 1, currentY, 0)
        Sleep(50)  ; Brief pause
        MouseMove(currentX, currentY, 0)

        ; Restore your original coordinate mode
        CoordMode("Mouse", "Client")
    }
}

UpdatePSEditWindow() {
    global PSEDITCTL
    if (WinExist(PS) && !PSEDITCTL) {
        ClassNNs := WinGetControls(PS)
        for index, item in ClassNNs {
            if InStr(item, "RICHEDIT") {
                PSEDITCTL := item
                return
            }
        }
    }
}

toggleRadMode(*) {
    global RADSMODE
    RADSMODE := !RADSMODE
    TooltipMessage := (RADSMODE ? "Rads Mode: on" : "Rads Mode: off")
    ToolTip(TooltipMessage, RADSMODE ? 500 : 0, 0)
}

genericControlSend(action, key) {
    if (RADSMODE) {
        WinActivate(PS)
        ControlSend(action, PSEDITCTL, PS)
    } else {
        Send(key)
    }
}

toggleDictation(*) {
    WinActivate(PS)
    ControlSend("{F4}", PSEDITCTL, PS)
}

nextField(*) {
    WinActivate(PS)
    ControlSend("{Tab}", PSEDITCTL, PS)
}

prevField(*) {
    WinActivate(PS)
    ControlSend("{Shift down}{Tab}{Shift up}", PSEDITCTL, PS)
}

backspace(*) {
    WinActivate(PS)
    ControlSend("{Backspace}", PSEDITCTL, PS)
}

newLine(*) {
    WinActivate(PS)
    ControlSend("{Enter}", PSEDITCTL, PS)
}

exitRadsMode(*) {
    if (RADSMODE) {
        toggleRadMode()
    }
}

getFieldStrength(*) {
    Send("^d")
    Sleep(500)
    Send("field{Enter}")
}

enableRadsMode(*) {
    global RADSMODE := true
    TooltipMessage := "Rads Mode: on"
    CoordMode "ToolTip", "Screen"
    ToolTip(TooltipMessage, 500, 0)
}

saveDraft(*) {
    WinActivate(PS)
    ControlSend("{F9}", PSEDITCTL, PS)
}

undo(*) {
    WinActivate(PS)
    ControlSend("{Ctrl Down}z{Ctrl Up}", PSEDITCTL, PS)
}

redo(*) {
    WinActivate(PS)
    ControlSend("{Ctrl Down}y{Ctrl Up}", PSEDITCTL, PS)
}

pick(num) {

    CoordMode "Mouse", "Screen"
    MouseGetPos &xpos, &ypos
    CoordMode "Mouse", "Client"
    heightRow := 17
    for n, ctrl in WinGetControls("PowerScribe")
    {
        if (ControlGetText(ctrl, "PowerScribe") == "Pick List Choices") {
            ControlGetPos(&x, &y, &w, &h, ctrl, "PowerScribe")
            pos := y + Integer(heightRow/2) + heightRow * num
            WinActivate("PowerScribe")
            MouseMove x+20, pos
            Click
            Sleep(250)
            Click
            CoordMode "Mouse", "Screen"
            MouseMove xpos, ypos
            nextField()
            return
    }
}
}

normal(*) {
    WinActivate(PS)
    Send("Normal")
    Sleep(100)
    nextField()
}

searchBiopsy(*) {
    WinActivate(EPIC_TITLE)
    Send("^{Space}")
    Sleep(200)
    Send("Biopsy")
    Sleep(200)
    Send("{Enter}")
    }


; Hotkey Bindings
$CapsLock::Ctrl
!b:: breakGlass()
!p:: loginSite()
!d:: getFieldStrength()
!f:: searchBiopsy()

!Space:: enableRadsMode()
$^d:: exitRadsMode()

#HotIf RADSMODE
$d:: toggleDictation()
$h:: saveDraft()
$f:: nextField()
$g:: prevField()
$s:: backspace()
$a:: newLine()
$q:: undo()
$w:: redo()
$e:: pick(1)
$r:: pick(2)
$!1:: pick(1)
$!2:: pick(2)
$!3:: pick(3)
$!4:: pick(4)
$!5:: pick(5)

;; Force send letters to visage
$z:: {
    WinActivate(VISAGE)
    Send("z")
    return
}

$x:: {
    WinActivate(VISAGE)
    Send("x")
    return
}

$c:: {
    WinActivate(VISAGE)
    Send("c")
    return
}

$v:: {
    WinActivate(VISAGE)
    Send("v")
    return
}


;; $r:: normal()

This script provides automation for common radiology tasks including EPIC integration, PowerScribe dictation controls, and workflow shortcuts. Download the full script using the link above.

Hotkey Bindings Reference

Complete keyboard shortcuts for the radiology automation script

Global Shortcuts

Caps Lock→ Ctrl

Alt + bBreak glass

Alt + pLogin site

Alt + dField strength

Alt + fSearch biopsy

Alt + SpaceEnable Rads Mode

Ctrl + dExit Rads Mode

Rads Mode - Dictation

dToggle dictation

hSave draft

fNext field

gPrevious field

sBackspace

aNew line

qUndo

wRedo

Pick Lists & Visage

ePick item 1

rPick item 2

Alt + 1-5Pick items 1-5

Visage viewer:

z, x, c, vSend to Visage

Installation & Usage

Step-by-step guide to install and configure the automation scripts

Installation Requirements

Download both files from the links above and extract them to the same directory. Run the .exe file to start the automation script.

Installation Steps

1Download the AutoHotkey + SciTE Bundle (runtime + editor)
2Download the Radiology Automation Script files
3Extract both archives to the same folder on your computer
4Run radiology.exe to start the script
5Configure your username and password in the GUI

Usage Tips

Use Alt + Space to enable Rads Mode for dictation shortcuts
Press Ctrl + d to exit Rads Mode when done
Caps Lock functions as Ctrl key for easier access
The launcher window minimizes after setup - close it to stop the script

Important Security Notes

Scripts are designed for specific radiology software (EPIC, PowerScribe, Visage)
Test thoroughly in a safe environment before clinical use
Keep credentials secure - never share configured script files
Customize hotkeys and window titles to match your specific setup